BaseAccountFactory

Deploys a new Account for admin.

function createAccount(address _admin, bytes calldata _data) external virtual override returns (address) {
    address impl = accountImplementation;
    bytes32 salt = _generateSalt(_admin, _data);
    address account = Clones.predictDeterministicAddress(impl, salt);
    if (account.code.length > 0) {
        return account;
    }
    account = Clones.cloneDeterministic(impl, salt);
    _initializeAccount(account, _admin, _data);
    emit AccountCreated(account, _admin);
    return account;
}

The address to be set as default admin role for the contract. Must be of type address.

If extra storage variables are required in your account contract, override this function, abi encode the variables, pass them to this function as a bytes type.

Callback function for an Account to register its signers.

function addSigner(address _signer) external {
    address account = msg.sender;
    bool isAlreadyAccount = accountsOfSigner[_signer].add(account);
    bool isAlreadySigner = signersOfAccount[account].add(_signer);
    if (!isAlreadyAccount || !isAlreadySigner) {
        revert("AccountFactory: signer already added");
    }
    emit SignerAdded(account, _signer);
}

The address of the signer to add to the account.

Callback function for an Account to un-register its signers.

function removeSigner(address _signer) external {
    address account = msg.sender;
    bool isAccount = accountsOfSigner[_signer].remove(account);
    bool isSigner = signersOfAccount[account].remove(_signer);
    if (!isAccount || !isSigner) {
        revert("AccountFactory: signer not found");
    }
    emit SignerRemoved(account, _signer);
}

The address of the signer to remove from the account.

Returns the address of an Account that would be deployed with the given admin signer.

function getAddress(address _adminSigner) public view returns (address) {
    bytes32 salt = _generateSalt(_admin, _data);
    return Clones.predictDeterministicAddress(accountImplementation, salt);
}

The admin signer for the account.

Returns all signers of an account.

function getSignersOfAccount(address account) external view returns (address[] memory signers) {
    return signersOfAccount[account].values();
}

The address of the account to get the signers of.

Returns all accounts that the given address is a signer of.

function getAccountsOfSigner(address signer) external view returns (address[] memory accounts) {
    return accountsOfSigner[signer].values();
}

The address of the signer to get the accounts of.

Called in createAccount. Initializes the account contract created in createAccount.

function _initializeAccount(
    address _account,
    address _admin,
    bytes calldata _data
) internal virtual;

The address of the smart account smart contract to initialize.

The address to be set as default admin role for the contract. Must be of type address.

If extra storage variables are required in your account contract, abi encode the variables, pass them to this function as the bytes argument.

For example:

 
function initializeAccount(
    address _admin,
    bytes calldata _data
) public override initializer {
    Account.initialize(_admin, _data);
}